FAQ e Tutoriais
Configurações de Email Downloads Hospedagem de Sites Painel de Controle HELM Registro de Domínios
BUSCAR
FAQ e Tutoriais: Hospedagem de Sites
Como enviar E-mail através do CDOSYS com SMTP Autenticado

O CDOSYS é a relação nova e melhorada da Microsoft para envio de e-mail, oferecendo toda a mesma funcionalidade que o CDONTS.
Abaixo segue um exemplo, de como utilizar o componente com SMTP Autenteticado:

<%
Dim objCDOSYSMail
Dim objCDOSYSCon
'CRIA A INSTÂNCIA COM O OBJETO CDOSYS
Set objCDOSYSMail = Server.CreateObject("CDO.Message")

'CRIA A INSTÂNCIA DO OBJETO PARA CONFIGURAÇÃO DO SMTP
Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")

'SERVIDOR DE SMTP, USE smtp.SeuDominio.com OU smtp.hostsys.com.br
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.hostsys.com.br"

'PORTA PARA COMUNICAÇÃO COM O SERVIÇO DE SMTP
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587

'PORTA DO CDO
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

'ATIVAR RECURSO DE SMTP AUTENTICADO
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1

'USUÁRIO PARA SMTP AUTENTICADO
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendusername") = " suporte@hostsys.com.br "

'SENHA DO USUÁRIO PARA SMTP AUTENTICADO
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "Senha do E-mail"

'TEMPO DE TIMEOUT (EM SEGUNDOS)
objCDOSYSCon.Fields("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30

'ATUALIZA A CONFIGURAÇÃO DO CDOSYS PARA ENVIO DO E-MAIL
objCDOSYSCon.Fields.update
Set objCDOSYSMail.Configuration = objCDOSYSCon

'NOME DO REMETENTE, E-MAIL DO REMETENTE
objCDOSYSMail.From = "Hostsys <suporte@hostsys.com.br>"

'NOME DO DESINATÁRIO, E-MAIL DO DESINATÁRIO
objCDOSYSMail.To = "Hostsys <suporte@hostsys.com.br>"

'CONFIGURA O E-MAIL QUE RECEBERÁ A RESPOSTA DESTA MENSAGEM
objCDOSYSMail.ReplyTo = "Hostsys <suporte@hostsys.com.br>"

'ASSUNTO DA MENSAGEM
objCDOSYSMail.Subject = "Teste do CDOSYS"

'CONTEÚDO DA MENSAGEM
objCDOSYSMail.TextBody = "Teste do componente CDOSYS"
'PARA ENVIO DA MENSAGEM NO FORMATO HTML, ALTERE O TextBody PARA HtmlBody
'objCDOSYSMail.HtmlBody = "<h1>Teste do componente CDOSYS</h1>"

'ENVIA A MENSAGEM
objCDOSYSMail.Send

'DESTRÓI OS OBJETOS
Set objCDOSYSMail = Nothing
Set objCDOSYSCon = Nothing

Response.write "Mensagem Enviada..."
%>
Comentários (0)
Postar um novo comentário
 
 
Nome:
E-mail:
Comentários: